fc4a0fd510
This adds defined anchor points for external modules to hook into the software install, config and service dependency chain. This allows external modules to manage software installation (virtualenv, containers, etc) and service management (pacemaker) without needing rely on resources that may change or be renamed. Change-Id: I0d18ec6ffe6b54c85773a6dabb0ed7b6f59a12f4
41 lines
1.7 KiB
Puppet
41 lines
1.7 KiB
Puppet
# == Class: ceilometer::deps
|
|
#
|
|
# Ceilometer anchors and dependency management
|
|
#
|
|
class ceilometer::deps {
|
|
# Setup anchors for install, config and service phases of the module. These
|
|
# anchors allow external modules to hook the begin and end of any of these
|
|
# phases. Package or service management can also be replaced by ensuring the
|
|
# package is absent or turning off service management and having the
|
|
# replacement depend on the appropriate anchors. When applicable, end tags
|
|
# should be notified so that subscribers can determine if installation,
|
|
# config or service state changed and act on that if needed.
|
|
anchor { 'ceilometer::install::begin': }
|
|
-> Package<| tag == 'ceilometer-package'|>
|
|
~> anchor { 'ceilometer::install::end': }
|
|
-> anchor { 'ceilometer::config::begin': }
|
|
-> Ceilometer_config<||>
|
|
~> anchor { 'ceilometer::config::end': }
|
|
-> anchor { 'ceilometer::db::begin': }
|
|
-> anchor { 'ceilometer::db::end': }
|
|
~> anchor { 'ceilometer::dbsync::begin': }
|
|
-> anchor { 'ceilometer::dbsync::end': }
|
|
~> anchor { 'ceilometer::service::begin': }
|
|
~> Service<| tag == 'ceilometer-service' |>
|
|
~> anchor { 'ceilometer::service::end': }
|
|
|
|
# policy config should occur in the config block also.
|
|
Anchor['ceilometer::config::begin']
|
|
-> Openstacklib::Policy::Base<||>
|
|
~> Anchor['ceilometer::config::end']
|
|
|
|
# Ensure files are modified in the config block
|
|
Anchor['ceilometer::config::begin']
|
|
-> File<| tag == 'event-pipeline' |>
|
|
~> Anchor['ceilometer::config::end']
|
|
|
|
# Installation or config changes will always restart services.
|
|
Anchor['ceilometer::install::end'] ~> Anchor['ceilometer::service::begin']
|
|
Anchor['ceilometer::config::end'] ~> Anchor['ceilometer::service::begin']
|
|
}
|