Add support for Dell EMC XtremIO Cinder ISCSI Backend

This change adds a new define for cinder::backend::dellemc_xtremio_iscsi,
allowing users to create multiple backend definitions within their puppet
manifests for use with Cinder.

Change-Id: I53577138e594739aebccaef5a8663483605424f9
Implements: blueprint support-dellemc-xtremio-cinder

manifests/backend/dellemc_xtremio_iscsi.pp

@@ -0,0 +1,85 @@
+# == define: cinder::backend::dellemc_xtremio_iscsi
+#
+# Configure the Dell EMC XtremIO Driver for cinder.
+#
+# === Parameters
+#
+# [*san_ip*]
+#   (required) IP address of XMS.
+#
+# [*san_login*]
+#   (required) XMS user name.
+#
+# [*san_password*]
+#   (required) XMS user password.
+#
+# [*xtremio_cluster_name*]
+#   (required) XMS cluster id in multi-cluster environment.
+#
+# [*volume_backend_name*]
+#   (optional) The storage backend name.
+#   Defaults to the name of the backend
+#
+# [*xtremio_array_busy_retry_count*]
+#   (optional) Number of retries in case array is busy.
+#   Defaults to 5
+#
+# [*xtremio_array_busy_retry_interval*]
+#   (optional) Interval between retries in case array is busy.
+#   Defaults to 5
+#
+# [*xtremio_volumes_per_glance_cache*]
+#   (optional) Number of volumes created from each cached glance image.
+#   Defaults to 100
+#
+# [*extra_options*]
+#   (optional) Hash of extra options to pass to the backend stanza.
+#   Defaults to: {}
+#   Example:
+#     { 'dellemc_xtremio_iscsi_backend/param1' => { 'value' => value1 } }
+#
+# [*manage_volume_type*]
+#   (Optional) Whether or not manage Cinder Volume type.
+#   If set to true, a Cinde Volume type will be created
+#   with volume_backend_name=$volume_backend_name key/value.
+#   Defaults to false.
+#
+define cinder::backend::dellemc_xtremio_iscsi (
+  $san_ip,
+  $san_login,
+  $san_password,
+  $xtremio_cluster_name,
+  $volume_backend_name               = $name,
+  $xtremio_array_busy_retry_count    = 5,
+  $xtremio_array_busy_retry_interval = 5,
+  $xtremio_volumes_per_glance_cache  = 100,
+  $manage_volume_type                = false,
+  $extra_options                     = {},
+) {
+
+  include ::cinder::deps
+
+  $driver = 'emc.xtremio.XtremIOISCSIDriver'
+  cinder_config {
+    "${name}/volume_backend_name":               value => $volume_backend_name;
+    "${name}/volume_driver":                     value => "cinder.volume.drivers.${driver}";
+    "${name}/san_ip":                            value => $san_ip;
+    "${name}/san_login":                         value => $san_login;
+    "${name}/san_password":                      value => $san_password, secret => true;
+    "${name}/xtremio_cluster_name":              value => $xtremio_cluster_name;
+    "${name}/xtremio_array_busy_retry_count":    value => $xtremio_array_busy_retry_count;
+    "${name}/xtremio_array_busy_retry_interval": value => $xtremio_array_busy_retry_interval;
+    "${name}/xtremio_volumes_per_glance_cache":  value => $xtremio_volumes_per_glance_cache;
+
+  }
+
+  if $manage_volume_type {
+    cinder_type { $volume_backend_name:
+      ensure     => present,
+      properties => ["volume_backend_name=${volume_backend_name}"],
+    }
+  }
+
+  create_resources('cinder_config', $extra_options)
+
+}

releasenotes/notes/xtremio-driver-b7cd300a24a64b01.yaml

@@ -0,0 +1,3 @@
+---
+features:
+  - Add Dell EMC XtremIO backend cinder iscsi driver support

spec/defines/cinder_backend_dellemc_xtremio_spec.rb

@@ -0,0 +1,71 @@
+require 'spec_helper'
+
+describe 'cinder::backend::dellemc_xtremio_iscsi' do
+
+  let (:config_group_name) { 'dellemc_xtremio_iscsi' }
+
+  let (:title) { config_group_name }
+
+  let :params do
+    {
+      :san_ip                => '172.23.8.101',
+      :san_login             => 'Admin',
+      :san_password          => '12345',
+      :xtremio_cluster_name  => 'Cluster01',
+    }
+  end
+
+  let :default_params do
+    {
+      :xtremio_array_busy_retry_count    => 5,
+      :xtremio_array_busy_retry_interval => 5,
+      :xtremio_volumes_per_glance_cache  => 100,
+    }
+  end
+
+  let :facts do
+    OSDefaults.get_facts({})
+  end
+
+  shared_examples_for 'dellemc_xtremio_iscsi volume driver' do
+    let :params_hash do
+      default_params.merge(params)
+    end
+
+    it 'configures cinder volume driver' do
+      is_expected.to contain_cinder__backend__dellemc_xtremio_iscsi(config_group_name)
+      is_expected.to contain_cinder_config("#{title}/volume_driver").with_value(
+            'cinder.volume.drivers.emc.xtremio.XtremIOISCSIDriver')
+      params_hash.each_pair do |config,value|
+        is_expected.to contain_cinder_config("#{config_group_name}/#{config}").with_value( value )
+      end
+    end
+  end
+
+
+  context 'with parameters' do
+    it_configures 'dellemc_xtremio_iscsi volume driver'
+  end
+
+  context 'dellemc_xtremio_iscsi backend with additional configuration' do
+    before do
+      params.merge!({:extra_options => {'dellemc_xtremio_iscsi/param1' => { 'value' => 'value1' }}})
+    end
+
+    it 'configure dellemc_xtremio_iscsi backend with additional configuration' do
+      is_expected.to contain_cinder_config('dellemc_xtremio_iscsi/param1').with({
+        :value => 'value1'
+      })
+    end
+  end
+
+  context 'dellemc_xtremio_iscsi backend with cinder type' do
+    before do
+      params.merge!({:manage_volume_type => true})
+    end
+    it 'should create type with properties' do
+      should contain_cinder_type('dellemc_xtremio_iscsi').with(:ensure => :present, :properties => ['volume_backend_name=dellemc_xtremio_iscsi'])
+    end
+  end
+
+end