1ed8e5b866
Currently idempotency in Ubuntu is broken because of the below change detected in collate in MySQL. ``` /Stage[main]/Keystone::Db::Mysql/Openstacklib::Db::Mysql[keystone]/ Mysql_database[keystone]/collate: collate changed 'utf8mb3_general_ci' to 'utf8_general_ci' ``` Similarly to what we observed in the past about charset[1], it seems MySQL in Ubuntu is automatically converting the collate value and that is causing the "unexpected" change detected in the 2nd puppet run. This fixes the idempotency by using utf8mb3_general_ci in Ubuntu to avoid the mismatch caused by internal translation. [1]085d356902Conflicts: manifests/ironic.pp (yoga to xena) Conflicts: manifests/octavia.pp (xena to wallaby) Backport note: This change also covers Panko which was retired during Xena cycle. Change-Id: I56f31397669d3d7b08aa2e9808947141e003ab0b (cherry picked from commit9c2d58221c) (cherry picked from commitb8ad2df96a) (cherry picked from commit8bf381e97b)
108 lines
3.7 KiB
Puppet
108 lines
3.7 KiB
Puppet
# Configure the Designate service
|
|
#
|
|
|
|
class openstack_integration::designate {
|
|
|
|
include openstack_integration::config
|
|
include openstack_integration::params
|
|
include openstack_integration::bind
|
|
|
|
openstack_integration::mq_user { 'designate':
|
|
password => 'an_even_bigger_secret',
|
|
before => Anchor['designate::service::begin'],
|
|
}
|
|
|
|
class { 'designate::db::mysql':
|
|
charset => $::openstack_integration::params::mysql_charset,
|
|
collate => $::openstack_integration::params::mysql_collate,
|
|
password => 'designate',
|
|
}
|
|
class { 'designate::logging':
|
|
debug => true,
|
|
}
|
|
class { 'designate':
|
|
default_transport_url => os_transport_url({
|
|
'transport' => 'rabbit',
|
|
'host' => $::openstack_integration::config::host,
|
|
'port' => $::openstack_integration::config::rabbit_port,
|
|
'username' => 'designate',
|
|
'password' => 'an_even_bigger_secret',
|
|
}),
|
|
rabbit_use_ssl => $::openstack_integration::config::ssl,
|
|
}
|
|
class { 'designate::db':
|
|
database_connection => 'mysql+pymysql://designate:designate@127.0.0.1/designate?charset=utf8'
|
|
}
|
|
|
|
include 'designate::client'
|
|
|
|
# TODO: Support SSL
|
|
class { 'designate::keystone::auth':
|
|
password => 'a_big_secret',
|
|
public_url => "http://${::openstack_integration::config::ip_for_url}:9001",
|
|
internal_url => "http://${::openstack_integration::config::ip_for_url}:9001",
|
|
admin_url => "http://${::openstack_integration::config::ip_for_url}:9001",
|
|
}
|
|
class { 'designate::keystone::authtoken':
|
|
password => 'a_big_secret',
|
|
user_domain_name => 'Default',
|
|
project_domain_name => 'Default',
|
|
auth_url => $::openstack_integration::config::keystone_admin_uri,
|
|
www_authenticate_uri => $::openstack_integration::config::keystone_auth_uri,
|
|
memcached_servers => $::openstack_integration::config::memcached_servers,
|
|
}
|
|
|
|
class { 'designate::api':
|
|
listen => "${::openstack_integration::config::ip_for_url}:9001",
|
|
api_base_uri => "http://${::openstack_integration::config::ip_for_url}:9001",
|
|
auth_strategy => 'keystone',
|
|
enable_api_v2 => true,
|
|
enable_api_admin => true
|
|
}
|
|
|
|
# IPv6 doesn't work for mdns ? https://bugs.launchpad.net/designate/+bug/1501396
|
|
class { 'designate::mdns':
|
|
listen => '127.0.0.1:5354'
|
|
}
|
|
|
|
class { 'designate::central': }
|
|
|
|
class { 'designate::producer': }
|
|
|
|
class { 'designate::worker': }
|
|
|
|
class { 'designate::backend::bind9':
|
|
rndc_host => '127.0.0.1',
|
|
rndc_config_file => '/etc/rndc.conf',
|
|
rndc_key_file => $::dns::params::rndckeypath,
|
|
}
|
|
|
|
# Validate that designate-central is ready for pool update
|
|
$command = "openstack --os-auth-url ${::openstack_integration::config::keystone_auth_uri} \
|
|
--os-identity-api-version 3 \
|
|
--os-project-name services --os-username designate --os-password a_big_secret \
|
|
--os-project-domain-name Default --os-user-domain-name Default zone list"
|
|
openstacklib::service_validation { 'designate-central':
|
|
command => $command,
|
|
timeout => '15',
|
|
refreshonly => true,
|
|
subscribe => Anchor['designate::service::end'],
|
|
}
|
|
|
|
# TODO: Implement pools.yaml management in puppet-designate
|
|
file { '/etc/designate/pools.yaml':
|
|
ensure => present,
|
|
content => template("${module_name}/pools.yaml.erb"),
|
|
require => Service['designate-central'],
|
|
}
|
|
|
|
exec { 'Update designate pools':
|
|
command => 'designate-manage pool update --file /etc/designate/pools.yaml',
|
|
path => '/usr/bin',
|
|
refreshonly => true,
|
|
logoutput => 'on_failure',
|
|
subscribe => File['/etc/designate/pools.yaml'],
|
|
require => Openstacklib::Service_validation['designate-central'],
|
|
}
|
|
}
|