OpenStack Swift Puppet Module
Go to file
Sebastien Badia 69031e85eb Prepare 6.1.0 release
Change-Id: I19c791d60c977eaefe6276730eba322c01a79ea2
2015-10-15 14:42:42 +02:00
ext Add test for keystone auth 2012-06-04 22:48:21 -07:00
files Drop ringbuilder.sh from swift module. 2013-04-10 10:08:54 -04:00
lib/puppet Fix ipv6 support 2015-04-07 12:54:14 +02:00
manifests Add max_header_size field for PKI tokens 2015-07-06 16:57:04 +03:00
spec acceptance: checkout stable/kilo puppet modules 2015-07-09 15:52:00 -04:00
templates Added rsyslog logging support to object-server 2015-05-03 21:22:12 -06:00
tests Add Puppet 4.x lint checks 2015-03-25 13:46:00 +01:00
.fixtures.yml Removal of SSH Components 2015-04-24 17:23:53 +02:00
.gemfile Update module to use puppetlabs_spec_helper gem 2012-05-31 17:11:07 -07:00
.gitignore Update gitignore file 2013-12-23 19:13:55 +01:00
.gitreview Update .gitreview file for project rename 2015-06-12 23:12:30 +00:00
CHANGELOG.md Prepare 6.1.0 release 2015-10-15 14:42:42 +02:00
Gemfile Use beaker-puppet_install_helper to install puppet 2015-06-30 16:58:59 -04:00
LICENSE Synchronize LICENSE file with OpenStack projects 2015-04-20 09:30:24 -04:00
README.md Prepare 6.1.0 release 2015-10-15 14:42:42 +02:00
Rakefile Disable 80chars/class_parameter_defaults checks 2013-08-12 17:50:21 -04:00
metadata.json Prepare 6.1.0 release 2015-10-15 14:42:42 +02:00

README.md

swift

6.1.0 - 2015.1 - Kilo

Table of Contents

  1. Overview - What is the swift module?
  2. Module Description - What does the module do?
  3. Setup - The basics of getting started with swift
  4. Reference - The classes, defines,functions and facts available in this module
  5. Implementation - An under-the-hood peek at what the module is doing
  6. Limitations - OS compatibility, etc.
  7. Development - Guide for contributing to the module
  8. Contributors - Those with commits

Overview

The swift module is a part of OpenStack, an effort by the Openstack infrastructure team to provide continuous integration testing and code review for Openstack and Openstack community projects as part of the core software. The module itself is used to flexibly configure and manage the object storage service for Openstack.

Module Description

The swift module is a thorough attempt to make Puppet capable of managing the entirety of swift. This includes manifests to provision such things as keystone, storage backends, proxies, and the ring. Types are shipped as part of the swift module to assist in manipulation of configuration files. The classes in this module will deploy Swift using best practices for a typical deployment.

This module is tested in combination with other modules needed to build and leverage an entire Openstack software stack. These modules can be found, all pulled together in the openstack module. In addition, this module requires Puppet's exported resources.

Setup

What the swift module affects

  • swift, the object storage service for Openstack.

Installing swift

example% puppet module install puppetlabs/swift

Beginning with swift

You much first setup exported resources.

To utilize the swift module's functionality you will need to declare multiple resources. The following is a modified excerpt from the openstack module. This is not an exhaustive list of all the components needed, we recommend you consult and understand the openstack module and the core openstack documentation.

Defining a swift storage node

class { 'swift':
  swift_hash_suffix => 'swift_secret',
}

swift::storage::loopback { ['1', '2']:
 require => Class['swift'],
}

class { 'swift::storage::all':
  storage_local_net_ip => $ipaddress_eth0
}

@@ring_object_device { "${ipaddress_eth0}:6000/1":
  region => 1, # optional, defaults to 1
  zone   => 1,
  weight => 1,
}
@@ring_container_device { "${ipaddress_eth0}:6001/1":
  zone   => 1,
  weight => 1,
}
@@ring_account_device { "${ipaddress_eth0}:6002/1":
  zone   => 1,
  weight => 1,
}

@@ring_object_device { "${ipaddress_eth0}:6000/2":
  region => 2,
  zone   => 1,
  weight => 1,
}
@@ring_container_device { "${ipaddress_eth0}:6001/2":
  region => 2,
  zone   => 1,
  weight => 1,
}
@@ring_account_device { "${ipaddress_eth0}:6002/2":
  region => 2,
  zone   => 1,
  weight => 1,
}

Swift::Ringsync<<||>>

Usage

Class: swift

Class that will set up the base packages and the base /etc/swift/swift.conf

class { 'swift': swift_hash_suffix => 'shared_secret', }

####swift_hash_suffix The shared salt used when hashing ring mappings.

Class swift::proxy

Class that installs and configures the swift proxy server.

class { 'swift::proxy':
  account_autocreate => true,
  proxy_local_net_ip => $ipaddress_eth1,
  port               => '11211',
}

####account_autocreate Specifies if the module should manage the automatic creation of the accounts needed for swift. This should be set to true if tempauth is also being used.

####proxy_local_net_ip This is the ip that the proxy service will bind to when it starts.

####port The port for which the proxy service will bind to when it starts.

Class: swift::storage

Class that sets up all of the configuration and dependencies for swift storage server instances.

class { 'swift::storage': storage_local_net_ip => $ipaddress_eth1, }

####storage_local_net_ip This is the ip that the storage service will bind to when it starts.

Class: swift::ringbuilder

A class that knows how to build swift rings. Creates the initial ring via exported resources and rebalances the ring if it is updated.

class { 'swift::ringbuilder':
  part_power     => '18',
  replicas       => '3',
  min_part_hours => '1',
}

####part_power The number of partitions in the swift ring. (specified as the power of 2)

####replicas The number of replicas to store.

####min_part_hours Time before a partition can be moved.

Define: swift::storage::server

Defined resource type that can be used to create a swift storage server instance. If you keep the sever names unique it is possibly to create multiple swift servers on a single physical node.

This will configure an rsync server instance and swift storage instance to manage the all devices in the devices directory.

swift::storage::server { '6010':
  type                 => 'object',
  devices              => '/srv/node',
  storage_local_net_ip => '127.0.0.1'
}

####namevar The namevar/title for this type will map to the port where the server is hosted.

####type The type of device, e.g. account, object, or container.

####device The directory where the physical storage device will be mounted.

####storage_local_net_ip This is the ip that the storage service will bind to when it starts.

Define: swift::storage::loopback

This defined resource type was created to test swift by creating a loopback device that can be used a storage device in the absent of a dedicated block device.

It creates a partition of size [$seek] at basedir/[$name] using dd with [$byte_size], formats is to be a xfs filesystem which is then mounted at [$mnt_base_dir]/[$name].

Then, it creates an instance of defined class for the xfs file system that will eventually lead the mounting of the device using the swift::storage::mount define.

swift::storage::loopback { '1':
  base_dir  => '/srv/loopback-device',
  mnt_base_dir => '/srv/node',
  byte_size => '1024',
  seek      => '25000',
}

####base_dir The directory where the flat files will be stored that house the file system to be loop back mounted.

####mnt_base_dir The directory where the flat files that store the file system to be loop back mounted are actually mounted at.

####byte_size The byte size that dd uses when it creates the file system.

####seek The size of the file system that will be created. Defaults to 25000.

Verifying installation

This modules ships with a simple Ruby script that validates whether or not your swift cluster is functional.

The script can be run as:

ruby $modulepath/swift/files/swift_tester.rb

Implementation

swift

swift is a combination of Puppet manifest and ruby code to delivery configuration and extra functionality through types and providers.

Limitations

  • No explicit support external NAS devices (i.e. Nexenta and LFS) to offload the ring replication requirements.

Beaker-Rspec

This module has beaker-rspec tests

To run:

shell bundle install bundle exec rspec spec/acceptance

Development

Developer documentation for the entire puppet-openstack project.

Contributors