Add gnocchi profiles

Implements: blueprint refactor-puppet-manifests

Co-Authored-By: Carlos Camacho <ccamacho@redhat.com>
Co-Authored-By: Juan Antonio Osorio Robles <jaosorior@redhat.com>

Change-Id: I38f218da118c45f3af1938eb17298017f4c70e24

manifests/profile/base/gnocchi.pp

@@ -0,0 +1,36 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::gnocchi
+#
+# Gnocchi profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+
+class tripleo::profile::base::gnocchi (
+  $step = hiera('step'),
+) {
+
+  if $step >= 3 {
+    include ::gnocchi
+    include ::gnocchi::config
+    include ::gnocchi::client
+  }
+}

manifests/profile/base/gnocchi/api.pp

@@ -0,0 +1,58 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::gnocchi::api
+#
+# Gnocchi profile for tripleo api
+#
+# === Parameters
+#
+# [*gnocchi_backend*]
+#   (Optional) Gnocchi backend string file, swift or rbd
+#   Defaults to swift
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*sync_db*]
+#   (Optional) Whether to run db sync
+#   Defaults to undef
+
+class tripleo::profile::base::gnocchi::api (
+  $gnocchi_backend = downcase(hiera('gnocchi_backend', 'swift')),
+  $step            = hiera('step'),
+  $sync_db         = true,
+) {
+
+  include ::tripleo::profile::base::gnocchi
+
+  if $step >= 3 and $sync_db {
+    include ::gnocchi::db::mysql
+    include ::gnocchi::db::sync
+  }
+
+  if $step >= 4 {
+    include ::gnocchi::api
+    include ::gnocchi::wsgi::apache
+    include ::gnocchi::storage
+    case $gnocchi_backend {
+      'swift': { include ::gnocchi::storage::swift }
+      'file': { include ::gnocchi::storage::file }
+      'rbd': { include ::gnocchi::storage::ceph }
+      default: { fail('Unrecognized gnocchi_backend parameter.') }
+    }
+  }
+}

manifests/profile/base/gnocchi/metricd.pp

@@ -0,0 +1,36 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::gnocchi::metricd
+#
+# Gnocchi metricd profile
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+
+class tripleo::profile::base::gnocchi::metricd (
+  $step = hiera('step'),
+) {
+
+  include ::tripleo::profile::base::gnocchi
+
+  if $step >= 4 {
+    include ::gnocchi::metricd
+  }
+}

manifests/profile/base/gnocchi/statsd.pp

@@ -0,0 +1,36 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::gnocchi::statsd
+#
+# Gnocchi statsd profile
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+
+class tripleo::profile::base::gnocchi::statsd (
+  $step = hiera('step'),
+) {
+
+  include ::tripleo::profile::base::gnocchi
+
+  if $step >= 4 {
+    include ::gnocchi::statsd
+  }
+}

manifests/profile/pacemaker/gnocchi.pp

@@ -0,0 +1,90 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::gnocchi
+#
+# Gnocchi Pacemaker HA profile for tripleo
+#
+# === Parameters
+#
+# [*gnocchi_indexer_backend*]
+#   (Optional) Gnocchi indexer backend
+#   Defaults to mysql
+#
+# [*bootstrap_node*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*sync_db*]
+#   (Optional) Whether to run db sync
+#   Defaults to undef
+#
+
+class tripleo::profile::pacemaker::gnocchi (
+  $gnocchi_indexer_backend = downcase(hiera('gnocchi_indexer_backend', 'mysql')),
+  $bootstrap_node  = hiera('bootstrap_nodeid'),
+  $step            = hiera('step'),
+  $sync_db         = true,
+) {
+
+  Service <| tag == 'gnocchi-service' |> {
+    hasrestart => true,
+    restart    => '/bin/true',
+    start      => '/bin/true',
+    stop       => '/bin/true',
+  }
+
+  if $::hostname == downcase($bootstrap_node) {
+    $pacemaker_master = true
+  } else {
+    $pacemaker_master = false
+  }
+
+  if $step >= 3 and $sync_db {
+    include ::gnocchi
+    include ::gnocchi::config
+    include ::gnocchi::client
+    if $gnocchi_indexer_backend == 'mysql' {
+      class { '::gnocchi::db::mysql':
+        require => Exec['galera-ready'],
+      }
+    }
+    include ::gnocchi::db::sync
+  }
+
+  if $step >= 5 and $pacemaker_master {
+
+    pacemaker::constraint::base { 'gnocchi-metricd-then-gnocchi-statsd-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::gnocchi::params::metricd_service_name}-clone",
+      second_resource => "${::gnocchi::params::statsd_service_name}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::gnocchi::params::metricd_service_name],
+        Pacemaker::Resource::Service[$::gnocchi::params::statsd_service_name]],
+    }
+    pacemaker::constraint::colocation { 'gnocchi-statsd-with-metricd-colocation':
+      source  => "${::gnocchi::params::statsd_service_name}-clone",
+      target  => "${::gnocchi::params::metricd_service_name}-clone",
+      score   => 'INFINITY',
+      require => [Pacemaker::Resource::Service[$::gnocchi::params::metricd_service_name],
+        Pacemaker::Resource::Service[$::gnocchi::params::statsd_service_name]],
+    }
+  }
+}

manifests/profile/pacemaker/gnocchi/api.pp

@@ -0,0 +1,46 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::gnocchi::api
+#
+# Gnocchi profile for tripleo api
+#
+# === Parameters
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*sync_db*]
+#   (Optional) Whether to run db sync
+#   Defaults to undef
+
+class tripleo::profile::pacemaker::gnocchi::api (
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+  $step             = hiera('step'),
+  $sync_db          = true,
+) {
+
+  include ::tripleo::profile::pacemaker::gnocchi
+
+  class { '::tripleo::profile::base::gnocchi::api':
+    step    => $step,
+    sync_db => (downcase($::hostname) == $pacemaker_master),
+  }
+}

manifests/profile/pacemaker/gnocchi/metricd.pp

@@ -0,0 +1,47 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::gnocchi::metricd
+#
+# Gnocchi metricd profile
+#
+# === Parameters
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+
+class tripleo::profile::pacemaker::gnocchi::metricd (
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+  $step             = hiera('step'),
+) {
+
+  include ::gnocchi::params
+  include ::tripleo::profile::pacemaker::gnocchi
+
+  if $step >= 4 and downcase($::hostname) == $pacemaker_master {
+
+    include ::gnocchi::metricd
+
+    pacemaker::resource::service { $::gnocchi::params::metricd_service_name :
+      clone_params => 'interleave=true',
+    }
+  }
+}

manifests/profile/pacemaker/gnocchi/statsd.pp

@@ -0,0 +1,47 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::gnocchi::statsd
+#
+# Gnocchi statsd profile
+#
+# === Parameters
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+
+class tripleo::profile::pacemaker::gnocchi::statsd (
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+  $step             = hiera('step'),
+) {
+
+  include ::gnocchi::params
+  include ::tripleo::profile::pacemaker::gnocchi
+
+  if $step >= 4 and downcase($::hostname) == $pacemaker_master {
+
+    include ::gnocchi::statsd
+
+    pacemaker::resource::service { $::gnocchi::params::statsd_service_name :
+      clone_params => 'interleave=true',
+    }
+  }
+}