puppet-tripleo/manifests/profile/base/ceilometer.pp

# Copyright 2016 Red Hat, Inc.
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may
# not use this file except in compliance with the License. You may obtain
# a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations
# under the License.
#
# == Class: tripleo::profile::base::ceilometer
#
# Ceilometer profile for tripleo
#
# === Parameters
#
# [*step*]
#   (Optional) The current step in deployment. See tripleo-heat-templates
#   for more details.
#   Defaults to hiera('step')
#
# [*oslomsg_rpc_proto*]
#   Protocol driver for the oslo messaging rpc service
#   Defaults to hiera('oslo_messaging_rpc_scheme', rabbit)
#
# [*oslomsg_rpc_hosts*]
#   list of the oslo messaging rpc host fqdns
#   Defaults to hiera('oslo_messaging_rpc_node_names')
#
# [*oslomsg_rpc_port*]
#   IP port for oslo messaging rpc service
#   Defaults to hiera('oslo_messaging_rpc_port', 5672)
#
# [*oslomsg_rpc_username*]
#   Username for oslo messaging rpc service
#   Defaults to hiera('oslo_messaging_rpc_user_name', 'guest')
#
# [*oslomsg_rpc_password*]
#   Password for oslo messaging rpc service
#   Defaults to hiera('oslo_messaging_rpc_password')
#
# [*oslomsg_rpc_use_ssl*]
#   Enable ssl oslo messaging services
#   Defaults to hiera('oslo_messaging_rpc_use_ssl', '0')
#
# [*oslomsg_notify_proto*]
#   Protocol driver for the oslo messaging notify service
#   Defaults to hiera('oslo_messaging_notify_scheme', rabbit)
#
# [*oslomsg_notify_hosts*]
#   list of the oslo messaging notify host fqdns
#   Defaults to hiera('oslo_messaging_notify_node_names')
#
# [*oslomsg_notify_port*]
#   IP port for oslo messaging notify service
#   Defaults to hiera('oslo_messaging_notify_port', 5672)
#
# [*oslomsg_notify_username*]
#   Username for oslo messaging notify service
#   Defaults to hiera('oslo_messaging_notify_user_name', 'guest')
#
# [*oslomsg_notify_password*]
#   Password for oslo messaging notify service
#   Defaults to hiera('oslo_messaging_notify_password')
#
# [*oslomsg_notify_use_ssl*]
#   Enable ssl oslo messaging services
#   Defaults to hiera('oslo_messaging_notify_use_ssl', '0')
#
# [*notifier_host_addr*]
#   (optional) Ip address of ceilometer notifier (edge qdr Endpoint)
#   Defaults to false
#
# [*notifier_host_port*]
#   (optional) Ceilometer notifier port
#   Defaults to undef
#
# [*event_pipeline_publishers*]
#   (Optional) A list of event pipeline publishers
#   Defaults to undef
#
# [*pipeline_publishers*]
#   (Optional) A list of pipeline publishers
#   Defaults to undef

class tripleo::profile::base::ceilometer (
  $step                      = Integer(hiera('step')),
  $oslomsg_rpc_proto         = hiera('oslo_messaging_rpc_scheme', 'rabbit'),
  $oslomsg_rpc_hosts         = any2array(hiera('oslo_messaging_rpc_node_names', undef)),
  $oslomsg_rpc_password      = hiera('oslo_messaging_rpc_password'),
  $oslomsg_rpc_port          = hiera('oslo_messaging_rpc_port', '5672'),
  $oslomsg_rpc_username      = hiera('oslo_messaging_rpc_user_name', 'guest'),
  $oslomsg_rpc_use_ssl       = hiera('oslo_messaging_rpc_use_ssl', '0'),
  $oslomsg_notify_proto      = hiera('oslo_messaging_notify_scheme', 'rabbit'),
  $oslomsg_notify_hosts      = any2array(hiera('oslo_messaging_notify_node_names', undef)),
  $oslomsg_notify_password   = hiera('oslo_messaging_notify_password'),
  $oslomsg_notify_port       = hiera('oslo_messaging_notify_port', '5672'),
  $oslomsg_notify_username   = hiera('oslo_messaging_notify_user_name', 'guest'),
  $oslomsg_notify_use_ssl    = hiera('oslo_messaging_notify_use_ssl', '0'),
  $notifier_host_addr        = false,
  $notifier_host_port        = undef,
  $event_pipeline_publishers = undef,
  $pipeline_publishers       = undef,
) {

  if $step >= 3 {
    warning('Ceilometer is deprecated and is going to be removed in future.')

    $oslomsg_rpc_use_ssl_real = sprintf('%s', bool2num(str2bool($oslomsg_rpc_use_ssl)))
    $oslomsg_notify_use_ssl_real = sprintf('%s', bool2num(str2bool($oslomsg_notify_use_ssl)))
    class { 'ceilometer' :
      default_transport_url      => os_transport_url({
        'transport' => $oslomsg_rpc_proto,
        'hosts'     => $oslomsg_rpc_hosts,
        'port'      => $oslomsg_rpc_port,
        'username'  => $oslomsg_rpc_username,
        'password'  => $oslomsg_rpc_password,
        'ssl'       => $oslomsg_rpc_use_ssl_real,
      }),
      notification_transport_url => os_transport_url({
        'transport' => $oslomsg_notify_proto,
        'hosts'     => $oslomsg_notify_hosts,
        'port'      => $oslomsg_notify_port,
        'username'  => $oslomsg_notify_username,
        'password'  => $oslomsg_notify_password,
        'ssl'       => $oslomsg_notify_use_ssl_real,
      }),
    }

    if $notifier_host_addr {
      class {'::ceilometer::agent::notification' :
        event_pipeline_publishers => concat(any2array(os_transport_url({
          'transport' => 'notifier',
          'host'      => $notifier_host_addr,
          'port'      => $notifier_host_port,
          'query'     => { 'driver' => 'amqp' },
        })), $event_pipeline_publishers),
        pipeline_publishers       => concat(any2array(os_transport_url({
          'transport' => 'notifier',
          'host'      => $notifier_host_addr,
          'port'      => $notifier_host_port,
          'query'     => { 'driver' => 'amqp' },
        })), $pipeline_publishers),
      }
    }
    else {
      class {'::ceilometer::agent::notification' :
        event_pipeline_publishers => $event_pipeline_publishers,
        pipeline_publishers       => $pipeline_publishers,
      }
    }
    include ceilometer::config
    include ceilometer::logging
  }
}